Copying blu ray with subtitles

MKV playback, recompression, remuxing, codec packs, players, howtos, etc.
Post Reply
Message
Author
TempGuy1
Posts: 9
Joined: Tue Jan 28, 2014 4:15 am

Copying blu ray with subtitles

#1 Post by TempGuy1 » Tue Jan 28, 2014 4:25 am

Forgive me if this is a newb question but I've searched the forums high and low and can't find an answer to my question.

How do you make a copy of a blu ray with subtitles? For example, "The Wolverine" has some scenes in Japanese where English subtitles should appear.

After I rip the MKV with MakeMKV (leaving the subtitles checked) how do I mux it and include the subtitles so they appear in playback? TSMuxer doesn't recognize the subtitles and won't add them. Is there a simple way or do you have to somehow extract the subtitles and use another program to add them back after it's muxed? Please help...I've turned a few disks into coasters attempting this.

To clarify, I'm making the disk Blu Ray compatible so it plays in standalone Blu Ray players.
Top
Chetwood
Posts: 982
Joined: Mon Aug 30, 2010 9:16 am

Re: Copying blu ray with subtitles

#2 Post by Chetwood » Tue Jan 28, 2014 5:52 am

If you really want a Bluray as output format, why use MakeMKV? And TSMuxer DOES recognize subs.
MultiMakeMKV: MakeMKV batch processing (Win)
MultiShrink: DVD Shrink batch processing
Offizieller Uebersetzer von DVD Shrink deutsch
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#3 Post by ndjamena » Tue Jan 28, 2014 12:36 pm

Extract the subtitles into .sup files first, then add the .sup files into TSMuxer along with the MKV.

As far as I can tell, TSMuxerGUI doesn't recognise PGS subtitles in Matroska Files.
Top
TempGuy1
Posts: 9
Joined: Tue Jan 28, 2014 4:15 am

Re: Copying blu ray with subtitles

#4 Post by TempGuy1 » Wed Jan 29, 2014 3:15 am

Chetwood wrote:If you really want a Bluray as output format, why use MakeMKV? And TSMuxer DOES recognize subs.
I extract the MKV, then if it's too big, handbrake it until it fits on a BD25 disk. When I throw the MKV into TSMuxer, it says "track not recognized" and subtitles don't output. Even if I throw an MKV that hasn't been encoded in handbrake, TSmuxer still doesn't recognize the subtitle track.
Top
TempGuy1
Posts: 9
Joined: Tue Jan 28, 2014 4:15 am

Re: Copying blu ray with subtitles

#5 Post by TempGuy1 » Wed Jan 29, 2014 3:16 am

ndjamena wrote:Extract the subtitles into .sup files first, then add the .sup files into TSMuxer along with the MKV.

As far as I can tell, TSMuxerGUI doesn't recognise PGS subtitles in Matroska Files.

How do I extract the subtitles?
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#6 Post by ndjamena » Wed Jan 29, 2014 3:24 am

MKVCleaver if you need a GUI or you could use MKVExtract directly, I have a batch that will do it automatically, but I've written a MediaInfo to Batch program using c++ that you'd need as well.
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#7 Post by ndjamena » Wed Jan 29, 2014 3:50 am

http://www.mediafire.com/download/54qxd ... aBatch.zip

I haven't had time to perfect it yet and you'll need the 32 bit MediaInfo.dll installed as well.

Extract - Subtitles.bat:

Code: Select all

@CALL Extract.bat "--folder" "D:\Videos2" "--subtitles" "ONLY" %*
Extract.bat:

Code: Select all

@if "%EMode%"=="" Set EMode=OFF
@ECHO %EMode%
SetLocal DisableDelayedExpansion

Set "Dest=D:\Ins2\"
Set "EXTLIST=*.mkv"
Set "Extract_Mode=folder"
Set "Extract_Folder=%Dest%"
Set "Add_File_Name=0"
Set "Add_Type_Enum=1"
Set "Sub_Folder="
Set "Video_Tog=1"
Set "Audio_Tog=1"
Set "Subtitles_Tog=1"
Set "D2V=0"
Set "DoPop="

if [%1]==[] (
	Set "Pattern=%EXTLIST%"
	CALL :START %1
)

:ARGS

	if [%1]==[] (
		EndLocal
		pause
		goto :eof
	)
	if /I "%~1"=="--addfilename" (
		if NOT [%2]==[] (
			if /I "%~2"=="OFF" (
				Set "Add_File_Name=0"
				SHIFT
			) else (
				if /I "%~2"=="ON" (
					Set "Add_File_Name=1"
					SHIFT
				) else (
					if "%Add_File_Name%"=="1" (
						Set "Add_File_Name=0"
					) else (
						Set "Add_File_Name=1"
					)
				)
			)
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--noenum" (
		Set "Add_Type_Enum=0"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--typeenumex" (
		Set "Add_Type_Enum=1"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--typeenum" (
		Set "Add_Type_Enum=2"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--ID" (
		Set "Add_Type_Enum=3"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--tracknum" (
		Set "Add_Type_Enum=4"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--UID" (
		Set "Add_Type_Enum=5"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--enum" (
		Set "Add_Type_Enum=6"
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--dump" (
		Set "Extract_Mode=dump"
		Set "Extract_Folder="
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--dumpasfolder" (
		Set "Extract_Mode=folder"
		Set "Extract_Folder="
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--dumpinfolder" (
		Set "Extract_Mode=dump"
		if NOT [%2]==[] (
			Set "Extract_Folder=%~2"
			if NOT EXIST "%~2" mkdir "%~2"
			SHIFT
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--folder" (
		Set "Extract_Mode=folder"
		if NOT [%2]==[] (
			Set "Extract_Folder=%~2"
			if NOT EXIST "%~2" mkdir "%~2"
			SHIFT
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--subfolder" (
		if NOT [%2]==[] (
			Set "Extract_Sub=%~2"
			if /I "%~2"=="None" Set "Extract_Sub="
			SHIFT
		) else (
			Set "Extract_Sub="
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--video" (
		if NOT [%2]==[] (
			if /I "%~2"=="OFF" (
				Set "Video_Tog=0"
				SHIFT
			) else (
				if /I "%~2"=="ON" (
					Set "Video_Tog=1"
					SHIFT
				) else (
					if /I "%~2"=="ONLY" (
						Set "Video_Tog=1"
						Set "Audio_Tog=0"
						Set "Subtitle_Tog=0"
						SHIFT
					) else (
						if /I "%~2"=="EXCEPT" (
							Set "Video_Tog=0"
							Set "Audio_Tog=1"
							Set "Subtitle_Tog=1"
							SHIFT
						) else (
							if "%Video_Tog%"=="1" (
								Set "Video_Tog=0"
							) else (
								Set "Video_Tog=1"
							)
						)
					)
				)
			)
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--audio" (
		if NOT [%2]==[] (
			if /I "%~2"=="OFF" (
				Set "Audio_Tog=0"
				SHIFT
			) else (
				if /I "%~2"=="ON" (
					Set "Audio_Tog=1"
					SHIFT
				) else (
					if /I "%~2"=="ONLY" (
						Set "Video_Tog=0"
						Set "Audio_Tog=1"
						Set "Subtitle_Tog=0"
						SHIFT
					) else (
						if /I "%~2"=="EXCEPT" (
							Set "Video_Tog=1"
							Set "Audio_Tog=0"
							Set "Subtitle_Tog=1"
							SHIFT
						) else (
							if "%Audio_Tog%"=="1" (
								Set "Audio_Tog=0"
							) else (
								Set "Audio_Tog=1"
							)
						)
					)
				)
			)
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--subtitles" (
		if NOT [%2]==[] (
			if /I "%~2"=="OFF" (
				Set "Subtitles_Tog=0"
				SHIFT
			) else (
				if /I "%~2"=="ON" (
					Set "Subtitles_Tog=1"
					SHIFT
				) else (
					if /I "%~2"=="ONLY" (
						Set "Video_Tog=0"
						Set "Audio_Tog=0"
						Set "Subtitle_Tog=1"
						SHIFT
					) else (
						if /I "%~2"=="EXCEPT" (
							Set "Video_Tog=1"
							Set "Audio_Tog=1"
							Set "Subtitle_Tog=0"
							SHIFT
						) else (
							if "%Subtitles_Tog%"=="1" (
								Set "Subtitles_Tog=0"
							) else (
								Set "Subtitles_Tog=1"
							)
						)
					)
				)
			)
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--d2v" (
		if NOT [%2]==[] (
			if /I "%~2"=="OFF" (
				Set "D2V=0"
				SHIFT
			) else (
				if /I "%~2"=="ON" (
					Set "D2V=1"
					SHIFT
				) else (
					if "%D2V%"=="1" (
						Set "D2V=0"
					) else (
						Set "D2V=1"
					)
				)
			)
		)
		SHIFT
		goto :ARGS
	)
	if /I "%~1"=="--reset" (
		Set "Extract_Mode=folder"
		Set "Extract_Folder=%Dest%"
		Set "Sub_Folder="
		Set "Video_Tog=1"
		Set "Audio_Tog=1"
		Set "Subtitle_Tog=1"
		Set "D2V=1"
		if NOT EXIST "%Dest%" mkdir "%Dest%"
		SHIFT
		goto :ARGS
	)
	if NOT EXIST %1 (
		SHIFT
		goto :ARGS
	)
	Set "Pattern=%EXTLIST%"
	if "%~f1"=="%CD%" (
		CALL :START %1
		SHIFT
		goto :ARGS
	)
	Type NUL
	pushd "%~f1" 2> nul
	if NOT "%errorlevel%"=="0" (
		if NOT "%CD%\"=="%~dp1" (
			pushd "%~dp1"
			Set "DoPop=1"
		)
		Set Pattern="%~nx1"
	) else (
		Set "DoPop=1"
	)
	CALL :START %1
	if "%DoPop%"=="1" (
		popd
		Set "DoPop="
	)
	SHIFT

goto :ARGS

:START

	if "%Extract_Folder%"=="" Set "Extract_Folder=\"
	if NOT "%Extract_Folder:~-1,1%"=="\" Set "Extract_Folder=%Extract_Folder%\"
	if "%Extract_Folder%"=="\" Set "Extract_Folder="
	
	if "%Extract_Sub%"=="" Set "Extract_Sub=\"
	if NOT "%Extract_Sub:~-1,1%"=="\" Set "Extract_Sub=%Extract_Sub%\"
	if "%Extract_Sub%"=="\" Set "Extract_Sub="
	
	for %%y in (%Pattern%) do (
		SetLocal DisableDelayedExpansion
		CALL :Process_File "%%~fy"
		EndLocal
	)

goto :eof

:Process_File

	cls
	Set "Source_Name=%~n1"
	Set "FolderName=%~n1"
	Set "ExtractList="
	Set "IndexCOM="
	Set "DoIndex="
	if NOT "%DEL_LIST%"=="" CALL :DEL_VARS
	
	if "%FolderName:~-1%"=="." (
		Set "FolderName=%FolderName%.dot"
	) else (
		if "%FolderName:~-4%"==".dot" (
			Set "FolderName=%FolderName%.dot"
		)
	)

	if "%Extract_Mode%"=="dump" (
		if "%Extract_Folder%"=="" (
			Set "FolderName=%~dp1"
		) else (
			Set "FolderName=%Extract_Folder%"
		)
	)
	
	if "%Extract_Mode%"=="folder" (
		if "%Extract_Folder%"=="" (
			Set "FolderName=%~dp1%FolderName%\"
			if NOT Exist "%~dp1%FolderName%\" mkdir "%~dp1%FolderName%\"
		) else (
			Set "FolderName=%Extract_Folder%%FolderName%\"
			if NOT Exist "%Extract_Folder%%FolderName%\" mkdir "%Extract_Folder%%FolderName%\"
		)
	)
	
	if NOT "%Extract_Sub%"=="" (
		Set "FolderName=%FolderName%%Extract_Sub%"
		if NOT Exist "%FolderName%%Extract_Sub%" mkdir "%FolderName%%Extract_Sub%"
	)
	
	Set AU=0
	Set ST=0
	Set VD=0
	
	echo Processing; "%~n1"

	for /f "tokens=1,2,*" %%g in ('MyMediaBatch.exe %1') do (
		CALL :Process_item %%g %%h "%%i" %1
	)
	
	Set /a Check=VD+AU+ST
	rem Set IndexCOM=
	echo.
	if "%Check%"=="0" (
		echo Nothing to do!
		timeout 3
	) else (
		echo Extracting Tracks;
		echo 0^|----^|10^|----^|20^|----^|30^|----^|40^|----^|50^|----^|60^|----^|70^|----^|80^|----^|90^|----^|
		Set "Progress_Var=0"
		for /f "tokens=1,*" %%j in ('MKVEXTRACT tracks %1%ExtractList%') do (
			echo %%j %%k>>"Z:\Work\Extract.log"
			if "%%j"=="Progress:" CALL :Progress_Bar "%%k"
		)
		CALL :Progress_Bar "100"
		echo.
		if NOT "%DoIndex%"=="" (
			echo.
			echo Creating Index File;
			echo 0^|----^|10^|----^|20^|----^|30^|----^|40^|----^|50^|----^|60^|----^|70^|----^|80^|----^|90^|----^|
			Set "Progress_Var=0"
			for /f "tokens=1,*" %%j in ('DGIndex.exe %IndexCOM%') do (
				echo %%j %%k>>"Z:\Work\Extract.log"
				CALL :Progress_Bar "%%j"
			)
			CALL :Progress_Bar "100"
			echo.
		)
	)

goto :eof

:Process_item

	if "%~1"=="Prg" (
		if "%~2"=="Err" (
			CALL ERROR: "%~f3"
			pause
		)
		goto :eof
	)
	if "%~1"=="File" goto :eof

	if "%~2"=="Start" (
		Set "Codec=None"
		goto :eof
	)

	if "%~2"=="End" (
		if "%Codec%"=="V_MPEG2" CALL :EXTRACT_TRACK_VD m2v "%~f4"
		if "%CodecStructure%"=="V_MS/VFW/FOURCC" CALL :EXTRACT_TRACK_VD avi "%~f4"
		rem if "%Codec%"=="WVC1" CALL :EXTRACT_TRACK_VD avi "%~f4"
		if "%Codec%"=="V_MPEG4/ISO/AVC" CALL :EXTRACT_TRACK_VD h264 "%~f4"
		if "%Codec:~0,7%"=="V_REAL/" CALL :EXTRACT_TRACK_VD real "%~f4"
		if "%Codec%"=="V_THEORA" CALL :EXTRACT_TRACK_VD ogg "%~f4"
		if "%Codec%"=="V_VP8" CALL :EXTRACT_TRACK_VD ivf "%~f4"
		if "%Codec%"=="V_VP9" CALL :EXTRACT_TRACK_VD ivf "%~f4"
		
		if "%Codec%"=="A_DTS" (
			if "%CodecEx%"=="MA" CALL :EXTRACT_TRACK_AU dts-ma "%~f4"
			if "%CodecEx%"=="HRA" CALL :EXTRACT_TRACK_AU dts-hra "%~f4"
			if "%CodecEx%"=="ES" CALL :EXTRACT_TRACK_AU dts-es "%~f4"
			if "%CodecEx%"=="" CALL :EXTRACT_TRACK_AU dts "%~f4"
		)
		if "%Codec%"=="A_TRUEHD" CALL :EXTRACT_TRACK_AU thd "%~f4"
		if "%Codec%"=="A_AC3" CALL :EXTRACT_TRACK_AU ac3 "%~f4"
		if "%Codec%"=="A_AAC" CALL :EXTRACT_TRACK_AU aac "%~f4"
		if "%Codec:~0,12%"=="A_AAC/MPEG2/" CALL :EXTRACT_TRACK_AU aac "%~f4"
		if "%Codec:~0,12%"=="A_AAC/MPEG2/" CALL :EXTRACT_TRACK_AU aac "%~f4"
		if "%Codec%"=="A_PCM/INT/LIT" CALL :EXTRACT_TRACK_AU wav "%~f4"
		if "%Codec%"=="A_MPEG/L2" CALL :EXTRACT_TRACK_AU m2p "%~f4"
		if "%Codec%"=="A_MPEG/L3" CALL :EXTRACT_TRACK_AU mp3 "%~f4"
		if "%Codec%"=="A_VORBIS" CALL :EXTRACT_TRACK_AU ogg "%~f4"
		if "%Codec:~0,7%"=="A_REAL/" CALL :EXTRACT_TRACK_AU real "%~f4"
		if "%Codec%"=="A_TTA1" CALL :EXTRACT_TRACK_AU tta "%~f4"
		if "%Codec%"=="A_ALAC" CALL :EXTRACT_TRACK_AU caf "%~f4"
		if "%Codec%"=="A_WAVPACK4" CALL :EXTRACT_TRACK_AU wv "%~f4"
		if "%Codec%"=="A_OPUS" CALL :EXTRACT_TRACK_AU ogg "%~f4"
		
		if "%Codec%"=="S_HDMV/PGS" CALL :EXTRACT_TRACK_ST sup "%~f4"
		if "%Codec%"=="S_VOBSUB" CALL :EXTRACT_TRACK_ST idx "%~f4"
		if "%Codec%"=="S_TEXT/UTF8" CALL :EXTRACT_TRACK_ST srt "%~f4"
		if "%Codec%"=="S_TEXT/SSA" CALL :EXTRACT_TRACK_ST ssa "%~f4"
		if "%Codec%"=="S_TEXT/ASS" CALL :EXTRACT_TRACK_ST ass "%~f4"
		if "%Codec%"=="S_KATE" CALL :EXTRACT_TRACK_ST ogg "%~f4"
		if "%Codec%"=="S_TEXT/USF" CALL :EXTRACT_TRACK_ST usf "%~f4"
		
		if "%Codec%"=="None" Set "Codec="
		
		CALL :DEL_VARS
		
		goto :eof
	)
	Set "%~2=%~3"
	Set "DEL_LIST=%DEL_LIST%%~2 "

goto :eof

:DEL_VARS

	for %%y in (%DEL_LIST%) do (
		set "%%y="
	)
	set "DEL_LIST="
	
goto :eof

:EXTRACT_TRACK_AU

	if "%Audio_Tog%"=="0" goto :eof
	Set /a AU=AU+1
	Set "File_Name="
	if "%Add_File_Name%"=="1" Set "File_Name=%Source_Name%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name% ("
	if "%Add_Type_Enum%"=="1" Set "File_Name=%File_Name%%TypeEnumEx%"
	if "%Add_Type_Enum%"=="2" Set "File_Name=%File_Name%%TypeEnum%"
	if "%Add_Type_Enum%"=="3" Set "File_Name=%File_Name%ID_%TrackID%"
	if "%Add_Type_Enum%"=="4" Set "File_Name=%File_Name%Track_#%ID%"
	if "%Add_Type_Enum%"=="5" Set "File_Name=%File_Name%UID_%UID%"
	if "%Add_Type_Enum%"=="6" Set "File_Name=%File_Name%Track_%TrackOrder%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name%)"
	Set ExtractList=%ExtractList% %TrackID%:"%FolderName%%File_Name%.%1"
	echo Track %TrackID%:"%FolderName%%File_Name%.%1"

goto :eof

:EXTRACT_TRACK_ST

	if "%Subtitle_Tog%"=="0" goto :eof
	Set /a ST=ST+1
	Set "File_Name="
	if "%Add_File_Name%"=="1" Set "File_Name=%Source_Name%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name% ("
	if "%Add_Type_Enum%"=="1" Set "File_Name=%File_Name%%TypeEnumEx%"
	if "%Add_Type_Enum%"=="2" Set "File_Name=%File_Name%%TypeEnum%"
	if "%Add_Type_Enum%"=="3" Set "File_Name=%File_Name%ID_%TrackID%"
	if "%Add_Type_Enum%"=="4" Set "File_Name=%File_Name%Track_#%ID%"
	if "%Add_Type_Enum%"=="5" Set "File_Name=%File_Name%UID_%UID%"
	if "%Add_Type_Enum%"=="6" Set "File_Name=%File_Name%Track_%TrackOrder%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name%)"
	Set ExtractList=%ExtractList% %TrackID%:"%FolderName%%File_Name%.%1"
	echo Track %TrackID%:"%FolderName%%File_Name%.%1"

goto :eof

:EXTRACT_TRACK_VD

	if "%Video_Tog%"=="0" goto :eof
	Set /a VD=VD+1
	Set "File_Name="
	if "%Add_File_Name%"=="1" Set "File_Name=%Source_Name%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name% ("
	if "%Add_Type_Enum%"=="1" Set "File_Name=%File_Name%%TypeEnumEx%"
	if "%Add_Type_Enum%"=="2" Set "File_Name=%File_Name%%TypeEnum%"
	if "%Add_Type_Enum%"=="3" Set "File_Name=%File_Name%ID_%TrackID%"
	if "%Add_Type_Enum%"=="4" Set "File_Name=%File_Name%Track_#%ID%"
	if "%Add_Type_Enum%"=="5" Set "File_Name=%File_Name%UID_%UID%"
	if "%Add_Type_Enum%"=="6" Set "File_Name=%File_Name%Track_%TrackOrder%"
	if "%Add_File_Name%"=="1" if NOT "%Add_Type_Enum%"=="0" Set "File_Name=%File_Name%)"
	Set ExtractList=%ExtractList% %TrackID%:"%FolderName%%File_Name%.%1"
	echo Track %TrackID%:"%FolderName%%File_Name%.%1"
	if "%D2V%"=="1" if "%1"=="m2v" (
		Set IndexCOM=-ia 3 -i "%FolderName%%File_Name%.%1" -o "%FolderName%%File_Name%" -hide -exit
		Set DoIndex=1
	)

goto :eof

:OUT_ERROR

	echo ERROR: %~1

goto :eof

:Progress_Bar

	
	if %~1 GTR %Progress_Var% (
		echo ?? | set /p Dummy=??
		Set /a Progress_Var+=5
	)
	if %~1 GTR %Progress_Var% goto :Progress_Bar
	TITLE Progress: %~1
	
goto :eof
Even easier than MKVCleaver...
Last edited by ndjamena on Thu Apr 17, 2014 3:37 am, edited 3 times in total.
Top
Chetwood
Posts: 982
Joined: Mon Aug 30, 2010 9:16 am

Re: Copying blu ray with subtitles

#8 Post by Chetwood » Wed Jan 29, 2014 6:25 am

TempGuy1 wrote:I extract the MKV, then if it's too big, handbrake it until it fits on a BD25 disk.
Again: why use MakeMKV when it does not compress? To resize BD structures you'd usually use DVDFab or something.
MultiMakeMKV: MakeMKV batch processing (Win)
MultiShrink: DVD Shrink batch processing
Offizieller Uebersetzer von DVD Shrink deutsch
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#9 Post by ndjamena » Wed Jan 29, 2014 8:20 am

MakeMKV is free while in Beta. Handbrake and TSMuxer are free, period.

My trial of DVDFab has expired, so I can't test to see if it's any better.
Top
Chetwood
Posts: 982
Joined: Mon Aug 30, 2010 9:16 am

Re: Copying blu ray with subtitles

#10 Post by Chetwood » Wed Jan 29, 2014 12:00 pm

The rip function of DVDfab stays free. Period.

And you too fail to explain why he would need MakeMKV to get from m2ts to m2ts.
MultiMakeMKV: MakeMKV batch processing (Win)
MultiShrink: DVD Shrink batch processing
Offizieller Uebersetzer von DVD Shrink deutsch
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#11 Post by ndjamena » Wed Jan 29, 2014 12:55 pm

Agreed, DVDFab is an option.

Handbrake should be able to read the DVDFab Blu Ray structure to get at the chapters and encode the Video. Then you add the Handbrake encode and the M2TS file to TSMuxer to create a Blu Ray.

Or, rip with MakeMKV, re-encode the file, extract the subtitles and add the Handbrake encode and the subtitles to TSMuxer to create a Blu Ray.

I guess it's a matter of personal preference.
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#12 Post by ndjamena » Sat Feb 01, 2014 9:48 pm

MakeMKV Back-up + BD Rebuilder looks promising, you even get to keep the menus.

http://www.videohelp.com/tools/BD-Rebuilder
Top
TempGuy1
Posts: 9
Joined: Tue Jan 28, 2014 4:15 am

Re: Copying blu ray with subtitles

#13 Post by TempGuy1 » Sun Feb 02, 2014 3:26 pm

Chetwood wrote:
TempGuy1 wrote:I extract the MKV, then if it's too big, handbrake it until it fits on a BD25 disk.
Again: why use MakeMKV when it does not compress? To resize BD structures you'd usually use DVDFab or something.

I guess I don't know any other way. I thought you need to make an MKV that bundles the audio and video and keeps chapters. Are you saying to use DVDfab to decrypt all the video files then somehow put them together? What about the movies that have lots of .m2ts files in one movie?
Top
TempGuy1
Posts: 9
Joined: Tue Jan 28, 2014 4:15 am

Re: Copying blu ray with subtitles

#14 Post by TempGuy1 » Sun Feb 02, 2014 3:28 pm

BTW, I found an easier way to keep forced subtitles. You can burn them in with handbrake during the encode to compress it. Then it's just burned in and don't have to worry at all about separate subtitle tracks. It works for me at least...I'm just making it up as I go.
Top
ndjamena
Posts: 830
Joined: Mon Jan 07, 2013 12:23 am

Re: Copying blu ray with subtitles

#15 Post by ndjamena » Sun Feb 02, 2014 11:25 pm

TempGuy1 wrote:
Chetwood wrote:
TempGuy1 wrote:I extract the MKV, then if it's too big, handbrake it until it fits on a BD25 disk.
Again: why use MakeMKV when it does not compress? To resize BD structures you'd usually use DVDFab or something.

I guess I don't know any other way. I thought you need to make an MKV that bundles the audio and video and keeps chapters. Are you saying to use DVDfab to decrypt all the video files then somehow put them together? What about the movies that have lots of .m2ts files in one movie?
DVDFab can make a BD25 out of a BD50 directly, but it's not part of the free HD Decrypter element of the program, so you'll only get the 30 day trial to use it. It's uses Quicksync by default on my computer, there is a software mode but I'm not sure what codec that is exactly. Other than that, it can rip the main movie to a BD structure and you can encode with handbrake or BD Rebuilder from there. I don't see how the free portions of DVDFab would make things any easier, but maybe I missed something.

Just keep doing what you're doing, at long as your happy with the outcome that's all that matters, as long as you don't make a mess of the handbrake settings it's doubtful anything can go wrong.
Top
Post Reply

Return to “MKV file processing and playback”